O Modelo Dinâmico de Turnovsky

Inicialização

> restart;

> with( DEtools ):

> with( plots ):

> with( linalg ):

> with( PDEtools ):

>

Warning, the name changecoords has been redefined

Warning, the name adjoint has been redefined

Warning, the protected names norm and trace have been redefined and unprotected

Equações Gerais (Descrições)

(1)

onde 0<D1<1, D2 < 0 e D3 >0

O produto real depende da renda disponível, da taxa real de juros, da riqueza real do setor privado e dos gastos do governo

(2)

A renda disponível depende do produto/renda nacional, dos impostos, dos juros provenientes dos títulos do governo e das perdas esperadas da riqueza financeira (o imposto inflacionário esperado).

(3)

A riqueza financeira consiste do estoque monetário mais o estoque dos títulos do governo em circulação.

(4)

onde, L1>0, L2<0 e

Esta é a curva LM, onde a oferta real de moeda depende da renda, da taxa nominal de juros e da riqueza financeira. De (3) nos temos que A depende de m e b. Por isso, L3 pode ser considerada uma medida da aversão ao risco (absoluto ou relativo: escolha de portfólio sobre incerteza).

(5)

Esta é a chamada curva de Phillips, onde a taxa de inflação efetiva (p= ) depende do desvio entre do produto em relação ao seu nível de pleno-emprego (natural) e da taxa esperada de inflação (uma vez que , isso reflete a ausência de ilusão monetária).

(6)

onde

Essa equação implica em uma expectativa adaptativa de inflação. (Em contraste, se utilizassemos a hipótese de expectativas recionais, teríamos que ). Isso reflete a idéia de Keynes sobre convenções em situações de incerteza (expectativas são formadas com base em experiências passadas: backward looking ).

(7)

ou

Essa relação descreve a taxa de acumulação de riqueza do setor privado, que por sua vez equivale ao orçamento do governo onde -p(m + b) é o "imposto inflacionário" das dívidas do governo. A partir dessa equação, temos que 4 instrumentos de política (dívida, moeda, taxas e gasto do governo) podem ser escolhidas de modo independente.

Substituindo (2) em (1), os efeitos de um aumento de r, A e são ambíguos, ou seja, um aumento em r (ou ) pode ter tanto um efeito renda positivo (negativo) como um efeito substituição negativo (positivo). Consideraremos então que:

(8a)

. O efeito substituição é maior que o efeito renda.

(8b)

. O efeito Mundell-Tobin é maior que o efeito "imposto inflacionário".

Um aumento em A também terá um efeito renda e riqueza. O sinal do efeito renda dependerá da forma com que a riqueza aumenta (seja por títulos ou moeda: b ou m). Assumiremos que:

(8c) e

(8d) e

Nesse modelo, as variáveis endógenas são:

e as exógenas são:

Condições Iniciais

Estoque real de títulos

> b := 10:

Estoque real de moeda

> m := 15:

Produto Natural

> Y_nat := 40:

Gastos do governo

> G := 15:

Impostos

> T := 20:

Derivadas Parciais

O impacto da renda real sobre os gastos privados

> D1 := 0.4:

O impacto da taxa real de juros sobre os gastos privados

> D2 := -12:

O impacto da riqueza financeira sobre os gastos privados

> D3 := 5:

A sensibilidade da demanda de moeda à variações na renda.

> L1 := 0.6:

A sensibilidade do demanda de moeda à variações da taxa nominal de juros.

> L2 := -0.9:

A sensibilidade da demanda de moeda a variações da riqueza financeira.

> L3 := 0.3:

Esse coeficiente representa os efeitos do desvio do produto sobre o nível de preços.

> alpha := 0.4:

Esse coeficiente representa a sensibilidade da taxa esperada de inflação ao erro de previsão efetivamente cometido.

> gama := 0.3:

Política de Fixação do Estoque Real de Moeda

Quando m é mantido constante, a política monetária torna-se passiva.

Redefinindo Equações:

(1a)

(4)

(5)

(6)

(7a)

Encontrando o equilíbrio instantâneo para Y, p e r, e assumindo que as equações (1a), (4) e (5) são lineares, temos que

> eq1a := Y = D1*Y-D1*T+D1*r*A-D1*r*m-D1*pi*A+D2*r-D2*pi+D3*A+G:

> eq4 := m =L1*Y+L2*r+L3*A:

> eq5 := p = alpha*Y-alpha*Y_nat+pi:

> inst_eq := solve({eq1a,eq4,eq5},{Y,p,r});

A solução algébrica das equações acima é:

O resultado acima foi obtido pela substituição dos valores dados.

Encontrando os valores para a taxa nominal de juros ao longo do tempo:

> r :=subs(A=A(t),subs(pi=infl(t),subs(inst_eq,r)));

Encontrado o valor do nível de preços ao longo do tempo:

> p :=subs(A=A(t),subs(pi=infl(t),subs(inst_eq,p)));

Derivadas Parciais:

O impacto da taxa de juros sobre os gastos privados (deve ser < 0)

> Dr := D1*b+D2;

O impacto da taxa esperada de inflação sobre os gastos privados (deve ser > 0)

> Dpi := -D1*A(t)-D2;

O impacto do estoque real de títulos sobre os gastos privados (deve ser > 0)

> Db := D3+(r-infl(t))*D1;

O impacto do estoque real de moeda sobre os gastos privados (deve ser > 0)

> Dm := D3-infl(t)*D1;

A relação abaixo deve ser > 0

> J2 := -L2*(1-D1)-L1*Dr;

Linearizando as Equações

Fazendo a expansão da Taylor das equações diferenciais acima em torno da posição de equilíbrio, temos que:

Obs: Uma vez que encontrados as equações para o equilíbrio instantâneo, assumiremos que r = r( ,A) e p = p( ,A)

Onde as derivadas parciais são:

(deve ser > 1)

> dpdpi:=1-(alpha*Dpi*L2)/J2;

(deve ser > 0) - Efeito riqueza forte

> dpdA := (alpha*(-L2*Db+Dr*L3))/J2;

(deve ser > 0)

> drdpi := (Dpi*L1)/J2;

(deve ser > 0)

> drdA := (L3*(1-D1)+Db*L1)/J2;

A partir de (6) e (7a), o equilíbrio em estado estacionário ( steady-state ) requer que:

e

Equação do locus

> eq6 := gama*(subs(inst_eq,p)-pi)=0;

> locus_infl := simplify(subs(A=A(t),solve(eq6,pi)));

Equação do locus

> eq7 := simplify(G-T+subs(inst_eq,r)*(A-m)-subs(inst_eq,p)*A=0);

> locus_A := subs(A=A(t),solve(eq7,pi));

Os valores dos estado estacionário precisam ser positivos (A>0 and >0), para fazer senti econômico.

> stdst_sol := solve({eq6,eq7},{A,pi});

Encontrando a solução que satisfaz A > 0 e > 0.

> num_sol:=1:
while subs(stdst_sol[num_sol],A)<0 or subs(stdst_sol[num_sol],pi)<0 do
num_sol := num_sol+1
end do:

> A_e:=subs(stdst_sol[num_sol],A)+1:

> pi_e:=subs(stdst_sol[num_sol],pi):

Evita que a simulação prossiga caso A<0 ou <0

> if A_e <0 or pi_e <0 then
stop
end if;

Temos assim que,

> eqdifpi:=diff(infl(t),t)=gama*(p-infl(t));

> eqdifA:=diff(A(t),t)=G-T+r*(A(t)-m)-p*A(t);

A matriz do sistem no nível de steady-state:

> J := matrix([[gama*(subs(A(t)=A_e,dpdpi)-1), gama*subs(A(t)=A_e,subs(infl(t)=pi_e,dpdA))],[A_e*(subs(A(t)=A_e,drdpi)-subs(A(t)=A_e,dpdpi))-m*subs(A(t)=A_e,drdpi), subs(A(t)=A_e,subs(infl(t)=pi_e,r))-subs(A(t)=A_e,subs(infl(t)=pi_e,p))+A_e*(subs(A(t)=A_e,subs(infl(t)=pi_e,drdA))-subs(A(t)=A_e,subs(infl(t)=pi_e,dpdA)))-m*subs(A(t)=A_e,subs(infl(t)=pi_e,drdA))]]);

O determinante da matriz:

> det(J);

O traço da matriz:

> trace(J);

Para a estabilidade, é necessário que Det > 0 e Trace < 0. Para tanto, é necessário que a taxa real de juros (r-p) seja baixa e mais: e .

Gráfico de Vetor de Forças

Período Empregado nas análises

> tempo := 0.24:

Definimos como condição inicial as proximidades do steady-state

> IC:=[A(0)=round(A_e),infl(0)=round(pi_e)]:

Limites do gráfico

> xmax := A_e*2;

> xmin := 0;

> ymax := pi_e*2.5;

> ymin := 0;

Verificando a trajetória da economia nas proximidade do steady-state

> curves:=DEplot({eqdifA,eqdifpi},[A(t),infl(t)],t=0..tempo,[IC],infl=ymin..ymax,A=xmin..xmax,color=black,arrows=large, linecolour=red,thickness=2):
linelocus_infl:=plot(locus_infl,A=xmin..xmax,infl=ymin..ymax,thickness=3,colour=blue):
linelocus_A:=plot(locus_A,A=xmin..xmax,infl=ymin..ymax,thickness=3,colour=green):
display(curves,linelocus_infl,linelocus_A);

Diagrama de Fases

Encontrando as equações da solução

> solucao_eqs:=dsolve({eqdifA,eqdifpi} union convert(IC,set), numeric, output=listprocedure,
range=0..tempo):

> dsolA := subs(solucao_eqs,A(t)):dsolinfl := subs(solucao_eqs,infl(t)):

> odeplot(solucao_eqs,[[t,A(t)],[t,infl(t)]],0..tempo,linestyle=1,legend=["Riqueza Financeira","Inflação"], labels=["",""]);

> dsolr:=subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,r))):
dsolp:=subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,p))):
dsolY:=subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,Y))):

> grafr:=plot(dsolr(t),t=0..tempo,color=blue,legend="Taxa de Juros", labels=["",""]):
grafp:=plot(dsolp(t),t=0..tempo,color=red,legend="Nível de Preços", labels=["",""]):
grafY:=plot(dsolY(t),t=0..tempo,color=magenta,legend="Produto", labels=["",""]):
display(grafr,grafp,grafY);

Taxa Nominal de Crescimento Monetário Constante

Nesse caso, a autoridade monetária permite que a oferta nominal de moeda aumente a uma taxa constante.

Redefinindo Equações:

(1a)

(4)

(5)

(6)

(7a)

(8)

Taxa de crescimento do estoque de moeda

> mu:=6;

> unassign('r','m','p');

Emboras as equações (1a), (4) e (5) não tenham sido alteradas, com zeramos os valores de m, r e p teremos que encontrar as soluções novamente.

> eq1a := Y = D1*Y-D1*T+D1*r*A-D1*r*m-D1*pi*A+D2*r-D2*pi+D3*A+G;

> eq4 := m =L1*Y+L2*r+L3*A;

> eq5 := p = alpha*Y-alpha*Y_nat+pi;

> inst_eq := solve({eq1a,eq4,eq5},{Y,p,r});

Encontrando do valor da taxa nominal do juros ao longo do tempo

> r :=subs(m=m(t),subs(A=A(t),subs(pi=infl(t),subs(inst_eq,r))));

Encontrando o valor da nível de preços ao longo do tempo

> p :=subs(m=m(t),subs(A=A(t),subs(pi=infl(t),subs(inst_eq,p))));

Derivadas Parciais:

O impacto da taxa de juros sobre os gastos privados (deve ser < 0)

> Dr := D1*b+D2;

O impacto da taxa esperada de inflação sobre os gastos privados (deve ser > 0)

> Dpi := -D1*A(t)-D2;

O impacto do estoque real de títulos sobre os gastos privados (deve ser > 0)

> Db := D3+(r-infl(t))*D1;

O impacto do estoque real de moeda sobre os gastos privados (deve ser > 0)

> Dm := D3-infl(t)*D1;

A relação abaixo deve ser > 0

> J2 := -L2*(1-D1)-L1*Dr;

(deve ser > 1)

> dpdpi:=1-(alpha*Dpi*L2)/J2;

(deve ser > 0) - Efeitos riqueza forte

> dpdA := (alpha*(-L2*Db+Dr*L3))/J2;

(deve ser > 0)

> drdpi := (Dpi*L1)/J2;

(deve ser > 0)

> drdA := (L3*(1-D1)+Db*L1)/J2;

> dpdm:=alpha*(L2*D1*r-Dr)/J2;

(deve ser < 0)

> drdm := (D1(1-L1*r)-1)/J2;

Linearizando as Equações

Fazendo a expansão da Taylor das equações diferenciais acima em torno da posição de equilíbrio, temos que:

Obs: Uma vez que encontrados as equações para o equilíbrio instantâneo, assumiremos que r = r( ,A) e p = p( ,A)

O equilíbrio em estado estacionário ( steady-state ) requer que:

, e .

Equação do locurs

> eq6 := gama*(subs(inst_eq,p)-pi)=0;

> locus_infl := subs(m=m(t),subs(A=A(t),solve(eq6,pi)));

Equação do locus

> eq7 := simplify(G-T+subs(inst_eq,r)*(A-m)-subs(inst_eq,p)*A=0);

> locus_A := subs(m=m(t),subs(A=A(t),solve(eq7,pi)));

Equação do locus

> eq8 := simplify(mu*m-subs(inst_eq,p)*m=0);

> locus_m := subs(m=m(t),subs(A=A(t),solve(eq8,pi)));

Os valores das variáveis em steady-state precisam ser positivas (A>0, m>0 e >0).

> stdst_sol2 := fsolve({eq6,eq7,eq8},{A,pi,m});

> A_e:=subs(stdst_sol2,A):

> m_e:=subs(stdst_sol2,m):

> pi_e:=mu:

Evita que a simulação continue, caso A<0, m<0 ou <0

> if A_e <0 or m_e <0 or pi_e <0 then
stop
end if;

> eqdifpi:=diff(infl(t),t)=gama*(p-infl(t));

> eqdifA:=diff(A(t),t)=G-T+r*(A(t)-m(t))-p*A(t);

> eqdifm:=diff(m(t),t)=m(t)*(mu-p);

Análise da Estabilidade

O valor da taxa nominal de juros em steady state

> r :=subs(m=m_e,subs(A=A_e,subs(pi=pi_e,subs(inst_eq,r))));

O valor do nível de preços em steady state

> p :=mu;

Derivadas parciais em steady-state

> Dr := D1*b+D2;

> Dpi := -D1*A_e-D2;

> Db := D3+(r-pi_e)*D1;

> Dm := D3-pi_e*D1;

> J2 := -L2*(1-D1)-L1*Dr;

> dpdpi:=1-(alpha*Dpi*L2)/J2;

> dpdA := (alpha*(-L2*Db+Dr*L3))/J2;

> drdpi := (Dpi*L1)/J2;

> drdA := (L3*(1-D1)+Db*L1)/J2;

> dpdm:=alpha*(L2*D1*r-Dr)/J2;

> drdm := (D1(1-L1*r)-1)/J2;

A matrix jacobiana em steady-state

> J2:= matrix([[(A_e*(drdpi-dpdpi)-m_e*dpdpi)-lambda, r-p+A_e*(drdA-dpdA)-m_e*dpdA, A_e*(drdm-dpdm)-m_e*dpdm-r], [-m_e*dpdpi, -m_e*dpdA-lambda, mu-p-m_e*dpdm],[gama*(dpdpi-1), gama*dpdA, gama*dpdm-lambda]]);

> detJ2 := det(J2);

A condição de Routh-Hurwitz diz que (Takayama, 1993 p. 343):

Uma condição necessária e suficiente é que as raízes da equação característica

tenham coeficientes reais, isso será atendido se e somente se

, ,...,

Por isso, em um sistema 3x3 isso significa que

, , ,

> coef_a1 := coeff(detJ2,lambda,2);

> coef_a2 := coeff(detJ2,lambda,1);

> coef_a3 := coeff(detJ2,lambda,0);

> coef_a1*coef_a2-coef_a3;

Gráfico de Vetor de Forças

Redefinindo o tempo de análise

> tempo:=3:

Definimos como condição inicial as proximidades do steady-state

> IC:=[A(0)=round(A_e),m(0)=round(m_e),infl(0)=round(pi_e)]:

Limites do Gráfico

> xmax := A_e*1.5;

> xmin := A_e*0.5;

> ymax := m_e*1.5;

> ymin := m_e*0.5;

> zmax:= pi_e+0.7;

> zmin :=pi_e-0.7;

Verificando a trajetória da economia nas proximidade do steady-state

> curves:=DEplot3d({eqdifA,eqdifm,eqdifpi},[A(t),m(t),infl(t)],t=0..tempo,m=ymin..ymax,A=xmin..xmax,[IC],method=classical[rk4],color=black,arrows=small, linecolour=red,thickness=3,orientation=[-139,69]):

> linelocus_infl:=plot3d(locus_infl,A=xmin..xmax,m=ymin..ymax,thickness=1,colour=blue):
linelocus_A:=plot3d(locus_A,A=xmin..xmax,m=ymin..ymax,thickness=1,colour=green):
linelocus_m:=plot3d(locus_m,A=xmin..xmax,m=ymin..ymax,thickness=1,colour=cyan):
display(curves,linelocus_infl,linelocus_A,linelocus_m,view=[xmin..xmax,ymin..ymax,zmin..zmax]);

Ou em movimento:

Powered by: JavaView

obs: Se o gráfico não aparecer, pressione "atualizar" no browser. Você precisa ter a máquina virtual java habilitada/instalada.

Para girar a figura, fazer um zoom na imagem, ou distorcer seus vértices, clique com o botão da direita e Movimente o Mouse

A imagem pode demorar um pouco para carregar.

Diagrama de Fases

Encontrando as equações da solução

> solucao_eqs2:=dsolve({eqdifA,eqdifm,eqdifpi,A(0)=round(A_e),m(0)=round(m_e),infl(0)=round(pi_e)}, numeric, method=classical[rk4], output=listprocedure):

> dsolA := subs(solucao_eqs2,A(t)):
dsolm := subs(solucao_eqs2,m(t)):
dsolinfl := subs(solucao_eqs2,infl(t)):

> odeplot(solucao_eqs2,[[t,A(t)],[t,m(t)],[t,infl(t)]],0..tempo,linestyle=1,legend=["Riqueza Financeira","Estoque Real de Moeda","Inflação"], labels=["",""]);

> dsolr:=subs(m=subs(solucao_eqs2,m(t)),subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,r)))):
dsolp:=subs(m=subs(solucao_eqs2,m(t)),subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,p)))):
dsolY:=subs(m=subs(solucao_eqs2,m(t)),subs(A=subs(solucao_eqs,A(t)),subs(pi=subs(solucao_eqs,infl(t)),subs(inst_eq,Y)))):

> dsolr(0);dsolp(0);dsolY(0);

TAKAYAMA, A. (1993). Analytical Methods in Economics . The University of Michigan Press : Michigan PP.342-345.

TURNOVSKY, Stephen J. (1995) Methods of macroeconomic dynamics . MIT Press. Cambridge (Mass.) pp. 15-55.