Modelo Neoclássico de Investimento com Custos de Ajustamento

Observações: Tratamos da resolução numérica do modelo de investimento com custos de ajustamento demonstrado no capítulo 8 (Investment) de Romer (1996). Sugerimos a leitura das páginas 367 a 387.

Inicialização

> restart;

> with( DEtools ):

> with( plots ):

> with( linalg ):

> with( PDEtools ):

Parâmetros

Considera-se que a função de lucros é:

E a função de custos é:

Coeficiente autônomo dos lucros

> a:=1.5;

Coeficiente que mede a lucratividade marginal do capital

> b:=0.5;

Taxa de juros (que deve ser igual ao custo marginal do capital)

> r:=0.5;

Coeficiente que determina a velocidade de ajuste

> alpha:=0.5;

Número de Firmas na Economia

> N:=1;

Equações

Equações do Modelo - Veja Romer (1996) eq. 8.23 e 8.24:

> eqs:={diff(K(t),t)=N*(q(t)-1)/alpha,diff(q(t),t)=r*q(t)-a+b*K(t)};

Encontrando o Locus:

> reta1:=solve(N*(q(t)-1)/alpha,q(t));

Encontrando o Locus:

> reta2:=solve(r*q(t)-a+b*K(t),q(t));

A seguir analisaremos o comportamento da economia a partir de 2 choques exógenos:

a) Uma guerra destrói metade do estoque de capital dessa economia.

b) O governo cobra um imposto proporcional aos lucros das empresas.

Para isso, utilizaremos a hipótese de "expectativas racionais", de modo que os agentes reagem instantâneamente a tais choques.

Trajetória de Sela (Destruição do Estoque de Capital)

> A:=matrix([[0, N/alpha], [b, r]]);

> eigenvalues(A);

Chamando and , então para o primeiro autovetor

> solve(r*u+b*v=-.7807764064*u,v);

> KE:='KE':qe:='qe':

Encontrando o ponto de equilíbrio.

> solve({0=-N/alpha+0*KE+N/alpha*qe,0=-a+b*KE+r*qe},{KE,qe});

Esta é a linha da trajetória de Sela:

> solve(K-2=-2.561552813*(q-1),q);

> curves:=DEplot(eqs,[K(t),q(t)],t=0..1,K=0.5..2.5,q=0.5..2,color=black,arrows=small, linecolour=red,thickness=1):

> linhalocus:=plot({reta2,reta1},K=0.5..2.5,q=0.5..2,thickness=3,colour=blue):

> linhafase:=PLOT(CURVES([[1,1],[1,1.390388203],[2,1]]),COLOUR(RGB,1.00000000,0.,0.), LINESTYLE(3),THICKNESS(3)):

> linhasela:=plot([-.3903882032*K+1.780776406],K=0.5..2.5,q=0.5..2,linestyle=3,colour=red):

> display(curves,linhalocus,linhafase,linhasela);

Com a destruição de metade do estoque de capital da economia, deixa-se a posição de
equilíbrio em K=2 para uma nova situação em que o estoque de capital é 1. Instantaneamente o
valor de mercado do capital existente aumenta e o q eleva-se até a trajetória de sela. Com um q
mais elevado, progressivamente o estoque de capital aumenta até o equilíbrio anterior com K=1 e q =1.

Evolução no Tempo (Destruição do Estoque de Capital)

Condições iniciais após a ajuste instâneo de q. Trata-se do valor de q sobre a trajetória de sela

> IC := {K(0)=1,q(0)=1.390388203};

> ode := dsolve(eqs union IC,{K(t),q(t)},type=numeric):

> linhaK:= PLOT(CURVES([[-2,2],[-0.1,2],[0,1]]),COLOUR(RGB,1.00000000,0.,0.), LINESTYLE(1),THICKNESS(1)):

> linhaq:= PLOT(CURVES([[-2,1],[-0.1,1],[0,1.390388203]]),COLOUR(RGB,0,1,0), LINESTYLE(1),THICKNESS(1)):

> curvas := odeplot(ode,[[t,K(t)],[t,q(t)]],0..10,numpoints=25):

> legenda :=PLOT(TEXT([9,1.95],'`K`',ALIGNBELOW),TEXT([9,1.1],'`q`',ALIGNBELOW)):

> display(curvas,legenda,linhaK,linhaq);

Abaixo temos a dinâmica do q de Tobin e do estoque de capital ao longo do tempo. Como podemos observar, após o choque que destrói metade do estoque de capital na economia o equilíbrio é alcançado novamente em um intervalo de aproximadamente 8 períodos.

Trajetória de Sela (Imposto Proporcional aos lucros)

Quando o goveno cobra um imposto sobre os lucros temos que

Este é o valor da alíquota dos impostos. Aliq =

> aliq:=0.3;

Trata-se da nova especidicação da equação diferencial do q de Tobin

> eqs1:={diff(K(t),t)=N*(q(t)-1)/alpha,diff(q(t),t)=r*q(t)-(1-aliq)*a+(1-aliq)*b*K(t)};

> nova_reta2:=solve(r*q(t)-(1-aliq)*a+(1-aliq)*b*K(t),q(t));

> B:=matrix([[0, N/alpha], [(1-aliq)*b, r]]);

> eigenvalues(B);

> solve(r*u+(1-aliq)*b*v=-.6232124598*u,v);

> solve(2*v=-.6232124598*u,v);

> KE:='KE':qe:='qe':

Encontrando o novo valor de equilíbrio da economia

> solve({0=-N/alpha+0*KE+N/alpha*qe,0=-(1-aliq)*a+(1-aliq)*b*KE+r*qe},{KE,qe});

Esta é a linha da trajetória de Sela:

> solve(K-1.571428571=-3.209178457*(q-1),q);

> curves:=DEplot(eqs1,[K(t),q(t)],t=0..1,[[K(0)=2,q(0)=.8664544732]],K=0.5..2.5,q=0.5..2,color=black,arrows=small, linecolour=red,thickness=1):

> linhalocus:=plot({nova_reta2,reta1},K=0.5..2.5,q=0.5..2,thickness=3,colour=blue):

> linhalocusantiga:=plot({reta2},K=0.5..2.5,q=0.5..2,thickness=2,linestyle=3,colour=blue):

> linhasela:=plot([-.3116062299*K+1.489666933],K=0.5..2.5,q=0.5..2,linestyle=3,colour=red):

> linhafase:=PLOT(CURVES([[2,1],[2,.8664544732],[1.571428571,1]]),COLOUR(RGB,1.00000000,0.,0.), LINESTYLE(3),THICKNESS(3)):

> display(curves,linhalocus,linhalocusantiga,linhafase,linhasela);

Com a introdução do imposto diminui o valor de q até a trajetória de sela. Então, devido ao
maior custo de reposição do capital há uma redução no estoque de capital até que o novo
equilíbrio em seja alcançado.

Evolução no Tempo (Imposto Proporcional aos lucros)

> IC := {K(0)=2,q(0)=.8664544732};

> ode := dsolve(eqs1 union IC,{K(t),q(t)},type=numeric):

> curvas := odeplot(ode,[[t,K(t)],[t,q(t)]],0..10,numpoints=25):

> linhaK:= PLOT(CURVES([[-2,2],[0,2]]),COLOUR(RGB,1.00000000,0.,0.), LINESTYLE(1),THICKNESS(1)):

> linhaq:= PLOT(CURVES([[-2,1],[-0.1,1],[0,.8664544732]]),COLOUR(RGB,0,1,0), LINESTYLE(1),THICKNESS(1)):

> legenda :=PLOT(TEXT([9,1.55],'`K`',ALIGNBELOW),TEXT([9,1.1],'`q`',ALIGNBELOW)):

> display(curvas,legenda,linhaK,linhaq);

Abaixo temos a dinâmica do q de Tobin e do estoque de capital ao longo do tempo. Novamente observamos que a economia retorna ao equilíbrio.

Referências

Romer, David (1996) - Advanced Macroeconomics . McGraw-Hill. New York